#version 330

in vec2 fragTexCoord;
in vec4 fragColor;

uniform sampler2D texture0;
uniform vec4 colDiffuse;

out vec4 finalColor;

// Edge detection.
uniform vec2 resolution;
uniform float edgeFactor;

// Color depth.
uniform float gamma;
uniform float colorCount;

void main()
{
  // Texel color fetching from texture sampler
  vec3 texelColor = texture(texture0, fragTexCoord.xy).rgb;

  // Color depth
  texelColor = pow(texelColor, vec3(gamma, gamma, gamma));
  texelColor = texelColor*colorCount;
  texelColor = floor(texelColor);
  texelColor = texelColor/colorCount;
  texelColor = pow(texelColor, vec3(1.0/gamma));

  // Edges.
  float x = 1.0/resolution.x;
  float y = 1.0/resolution.y;

  vec4 horizEdge = vec4(0.0);
  horizEdge -= texture(texture0, vec2(fragTexCoord.x - x, fragTexCoord.y - y))*1.0;
  horizEdge -= texture(texture0, vec2(fragTexCoord.x - x, fragTexCoord.y   ))*2.0;
  horizEdge -= texture(texture0, vec2(fragTexCoord.x - x, fragTexCoord.y + y))*1.0;
  horizEdge += texture(texture0, vec2(fragTexCoord.x + x, fragTexCoord.y - y))*1.0;
  horizEdge += texture(texture0, vec2(fragTexCoord.x + x, fragTexCoord.y   ))*2.0;
  horizEdge += texture(texture0, vec2(fragTexCoord.x + x, fragTexCoord.y + y))*1.0;

  vec4 vertEdge = vec4(0.0);
  vertEdge -= texture(texture0, vec2(fragTexCoord.x - x, fragTexCoord.y - y))*1.0;
  vertEdge -= texture(texture0, vec2(fragTexCoord.x    , fragTexCoord.y - y))*2.0;
  vertEdge -= texture(texture0, vec2(fragTexCoord.x + x, fragTexCoord.y - y))*1.0;
  vertEdge += texture(texture0, vec2(fragTexCoord.x - x, fragTexCoord.y + y))*1.0;
  vertEdge += texture(texture0, vec2(fragTexCoord.x    , fragTexCoord.y + y))*2.0;
  vertEdge += texture(texture0, vec2(fragTexCoord.x + x, fragTexCoord.y + y))*1.0;

  vec3 edge = sqrt((horizEdge.rgb*horizEdge.rgb) + (vertEdge.rgb*vertEdge.rgb));
  float edgeGray = (edge.r + edge.g + edge.b) / 3.0;
  edge = vec3(edgeGray, 0.0, edgeGray);

  finalColor = vec4(texelColor + (edge * edgeFactor), 1.0);
}